Комментарии / Публикации kvashnin007 / OpenTraders - блогплатформа для трейдеров финансовых рынков

НЕВАЛЯШКА. Что за зверь такой? / Блог им. kvashnin007 25
0
Руслан предоставил мне сову. Я пообрезал излишний жирок. Так удобнее. Добывающая часть осталась без изменений.
С разрешения Руслана выкладываю его для обсуждения.
//+------------------------------------------------------------------+
//|                                            EA_Reversal v.1.0.mq4 |
//|                              Copyright 2017, wayfarer to Ispolin |
//+------------------------------------------------------------------+
#property copyright "Copyright 2018, wayfarer to Ispolin"
#property link      "http://forum.roboforex.ru/showthread.php?t=40284&page=72&p=1223715&viewfull=1#post1223715"
#property description "По царскому указу Ispolin, сотворен робот от числа 29.07.17"
#property description "Модификация от 25.04.18"
#property version   "1.00"
#property strict

#define MODE_BUY   0
#define MODE_SELL  1

//--- input parameters
input double   Lot         = 0.05;    // Лот базовый
input int      StopLoss    = 371;     // Потери в пунктах
input int      TakeProfit  = 352;     // Прибыль в пунктах
input double   Martingale  = 2.2;     // Коэф. увеличения лота
input int      Slip        = 30;      // проскальзывание
input int      Magic       = 1961;    // проскальзывание

struct CHK 
   {bool SL; 
   bool TP; 
   int OrdType; 
   int Cnt; 
   double Lots;
   };
CHK ChkPos;
int Dec;
int ModeTrade = 1;       // Первая сделка
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
{
     Dec=DecStep();
   return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
{
   bool Buy=false, Sell=false;   
   ChkPos.SL=false;
   ChkPos.TP=false;
   ChkPos.OrdType=-1;
   ChkPos.Lots=Lot;
   double StopLevel=MarketInfo(Symbol(),MODE_STOPLEVEL);
   
   int CntPos=CheckPos();
     
   if (CntPos==0)     // нет позиций и ордеров 
      {
      if (ChkPos.SL)  // последняя сделка закрылась в убыток
         {
         // переворот направления
         Sell= ChkPos.OrdType==OP_BUY;
         Buy = ChkPos.OrdType==OP_SELL;
         }
      else // направление сделки согласно настроек
         {
         Buy = ModeTrade==MODE_BUY;      //????????????????????????????????????????????
         Sell= ModeTrade==MODE_SELL;
         }
     
      if (ChkPos.TP)   // последняя сделка закрылась в профит
         {
         Buy = ChkPos.OrdType==OP_BUY;   //????????????????????????????????????????????
         Sell= ChkPos.OrdType==OP_SELL;
         }
      }
   if (Buy)
      {
      double Lots= GetCurLot();
      double SL = StopLoss  >0 ? NormalizeDouble(Ask-  StopLoss*Point,Digits) : 0;
      double TP = TakeProfit>0 ? NormalizeDouble(Ask+TakeProfit*Point,Digits) : 0;
      if (Lots>0) 
         OpenOrd(OP_BUY, Lots, Ask, SL, TP);
      }
   if (Sell)
      {
      double Lots= GetCurLot();
      double SL = StopLoss  >0 ? NormalizeDouble(Bid+  StopLoss*Point,Digits) : 0;
      double TP = TakeProfit>0 ? NormalizeDouble(Bid-TakeProfit*Point,Digits) : 0;
      if (Lots>0) OpenOrd(OP_SELL, Lots, Bid, SL, TP);   
      }
}
//-------------------------------------------------------------------------------
bool OpenOrd(int nMode, double Lots, double Price=0, double SL=0, double TP=0)
{
   bool ret=false, DataReady=false;
   int err, i=1;
   double PriceMarket, StopLevel=MarketInfo(Symbol(),MODE_STOPLEVEL);
   color ClrPos=White;
   PriceMarket=0;
   
   while (i<=5 && !IsStopped())
      {
      RefreshRates();
      if (nMode==OP_BUY)
         {
         Price      =Price>0 ? Price : Ask;
         PriceMarket=Ask;
         ClrPos=Blue;
         DataReady=true;
         }
      if (nMode==OP_SELL)
         {
         Price      =Price>0 ? Price : Bid;
         PriceMarket=Bid;
         ClrPos=Red;
         DataReady=true;
         }
      // если данные готовы запускаем ордер
      if (DataReady)
         {
         if (OrderSend(Symbol(), nMode, Lots, Price, Slip, SL, TP," ",Magic,0,ClrPos)>0)
            {
            ret=true;
            break;
            }
         else
            {
            DataReady=false;
            i++;
            err = GetLastError();
            
            if (err==ERR_SERVER_BUSY   ||
                err==ERR_NO_CONNECTION ||
                err==ERR_MARKET_CLOSED ||
                err==ERR_BROKER_BUSY   ||
                err==ERR_REQUOTE       ||
                err==ERR_TRADE_CONTEXT_BUSY)
               {
               Sleep(i*5000);
               Print("Открываю ордер, попыта № ", i);
               continue;
               }

            if (err==ERR_INVALID_PRICE ||
                err==ERR_INVALID_STOPS ||
                err==ERR_INVALID_TRADE_VOLUME)
               {
               Print("Цена  рынка=", PriceMarket);
               Print("Цена ордера=", Price);
               Print("Цена     SL=", SL);
               Print("Цена     TP=", TP);
               Print("Лот=", Lots);
               }
            break;
            }
         }
      else break;
      }
   return(ret);
}
// --------------------------------------------------------------------
double GetCurLot()
{
   string Symb     = Symbol();                             // Финансовый инструм.
   double One_Lot  = MarketInfo(Symb,MODE_MARGINREQUIRED); //Стоим. 1 лота
   double Min_Lot  = MarketInfo(Symb,MODE_MINLOT);         // Мин. размер. лотов
   double Max_Lot  = MarketInfo(Symbol(),MODE_MAXLOT);     // Макс. размер. лотов
   double Step     = MarketInfo(Symb,MODE_LOTSTEP);        //Шаг изменен размера
   double Free     = AccountFreeMargin();                  // Свободные средства
   double Lots_New = Lot;
   
   if (ChkPos.SL) Lots_New=NormalizeDouble(ChkPos.Lots*Martingale,Dec);
   if (Lots_New>0)
      {
      // Средств НЕ хватает.
      if(Lots_New*One_Lot>AccountFreeMargin())      
         // Расчёт лота
         Lots_New=NormalizeDouble(MathFloor(Free/One_Lot/Step)*Step, Dec);
      }
   if (Lots_New < Min_Lot) 
      Lots_New=Min_Lot;    // миниамальный
   if (Lots_New > Max_Lot) 
      Lots_New=Max_Lot;    // максимальный
   if  (Lots_New*One_Lot > AccountFreeMargin()) // Не хватает даже на минимальн. лот<img src='http://opentraders.ru/templates/skin/g6h/images/smilies/005.gif' alt=' ( '> 
      {
      Print("Не достаточно средств для минимального лота"); // Сообщение..
      return(0);                                // ..и выход 
      }
   return(Lots_New);
}
//------------------------------------------------------------------
int CheckPos()
{
   int Cnt=0;
   for (int i = OrdersTotal() -1; i >=0; i--)
     if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES))
        if (OrderSymbol() == Symbol() && OrderMagicNumber() == Magic)
          Cnt++;
   //---       
   ChkPos.Cnt=Cnt;
   for (int trade = OrdersHistoryTotal()-1; trade >=0; trade--)
      if(OrderSelect(trade,SELECT_BY_POS,MODE_HISTORY))
         if (OrderSymbol() == Symbol() && OrderMagicNumber() == Magic && (OrderType()==OP_BUY || OrderType()==OP_SELL))
            {
            if (StringFind(OrderComment(),"[sl]")>-1 && iBarShift(NULL,0,OrderCloseTime())==0 && Cnt==0)
               {
               ChkPos.OrdType=OrderType();
               ChkPos.SL=true;
               ChkPos.Lots=OrderLots();
               break;
               }
            if (StringFind(OrderComment(),"[tp]")>-1 && iBarShift(NULL,0,OrderCloseTime())==0 && Cnt==0)
               {
               ChkPos.OrdType=OrderType();
               ChkPos.TP=true;
               ChkPos.Lots=OrderLots();
               break;
               }
            }
   return(Cnt);
}
// --------------------------------------------------------
int DecStep() // разрядность лотов
{
   double step = MarketInfo(Symbol(),MODE_LOTSTEP);
   int dec=2;
   if (0.01<=step && step<0.1) dec=2;
   if (0.1<= step && step<1)   dec=1;
   if (  1<= step && step<10)  dec=0;
   return(dec);
}
// ------------------------------------------------------------
Авторизация

Новости сообщества:

Рейтинг брокеров FOREX

Из недавнего:
